home *** CD-ROM | disk | FTP | other *** search
/ TPUG - Toronto PET Users Group / TPUG Users Group CD / TPUG Users Group CD.iso / AMIGA / AMICUS / AMICUS13.ADF / FutureSound / future.asm < prev    next >
Assembly Source File  |  1986-08-05  |  12KB  |  436 lines
  1.  
  2. ************************************************************************
  3. *                                                                      *
  4. *   FUTURE.ASM                                                         *
  5. *                                                                      *
  6. *   Copyright (C) 1985, Commodore Amiga Inc.  All rights reserved.     *
  7. *                                                                      *
  8. *   Portions copyright 1986 Applied Visions, 15 Oak Ridge Road,        *
  9. *           Medford, Mass. 02155  (617) 488-3602                       *
  10. *                                                                      *
  11. ************************************************************************/
  12.  
  13. *************************************************************************
  14. *
  15. * future sound library source
  16. *   based on mylib.asm, from RKM 1.1 Vol. 2 Appendix, and Errata 1.1 disk
  17. *
  18. *   V1.0 by John Foust, for Applied Visions, 22-Jun-86.
  19. *
  20. * Source Control
  21. * ------ -------
  22. * 
  23. * $Header: amain.asm,v 31.3 86/06/20 18:58:00 jjf Exp $
  24. *
  25. * $Locker: john foust $
  26. *
  27. * $Log:   amain.asm,v $
  28. *
  29. ************************************************************************/
  30.  
  31.    SECTION  text,CODE
  32.  
  33.    NOLIST
  34.    include "exec/types.i"
  35.    include "exec/nodes.i"
  36.    include "exec/lists.i"
  37.    include "exec/libraries.i"
  38.    include "exec/alerts.i"
  39.    include "exec/initializers.i"
  40.    include "exec/resident.i"
  41.    include "libraries/dos.i"
  42.  
  43.    include "asmsupp.i"
  44.  
  45.    include "future.i"
  46.  
  47.    LIST
  48.  
  49.    ;------ These don't have to be external, but it helps some
  50.    ;------ debuggers to have them globally visible
  51.    XDEF   Init
  52.    XDEF   Open
  53.    XDEF   Close
  54.    XDEF   Expunge
  55.    XDEF   Null
  56.    XDEF   myName
  57.  
  58. ; These are the external Lattice C functions for FutureSound
  59. ; They were compiled with stack checking off, with '-v' on lc2.
  60.  
  61.    XDEF   FSGetSize
  62.    XDEF   FSLoadSound
  63.    XDEF   FSPlaySound
  64.    XDEF   FSStopSound
  65.  
  66.    XREF   _GetSize
  67.    XREF   _LoadSound
  68.    XREF   _PlaySound
  69.    XREF   _StopSound
  70.  
  71. ; These are used by the library for the startup code.
  72.  
  73.    XREF   _AbsExecBase
  74.  
  75.    XLIB   OpenLibrary
  76.    XLIB   CloseLibrary
  77.    XLIB   Alert
  78.    XLIB   FreeMem
  79.    XLIB   Remove
  80.  
  81.  
  82.    ; The first executable location.  This should return an error
  83.    ; in case someone tried to run you as a program (instead of
  84.    ; loading you as a library).
  85.  
  86. Start:
  87.    CLEAR   d0
  88.    rts
  89.  
  90. ;-----------------------------------------------------------------------
  91. ; A romtag structure.  Both "exec" and "ramlib" look for
  92. ; this structure to discover magic constants about you
  93. ; (such as where to start running you from...).
  94. ;-----------------------------------------------------------------------
  95.  
  96.    ; Most people will not need a priority and should leave it at zero.
  97.    ; the RT_PRI field is used for configuring the roms.  Use "mods" from
  98.    ; wack to look at the other romtags in the system
  99. MYPRI   EQU   0
  100.  
  101. initDDescrip:
  102.                ;STRUCTURE RT,0
  103.      DC.W    RTC_MATCHWORD ; UWORD RT_MATCHWORD
  104.      DC.L    initDDescrip  ; APTR  RT_MATCHTAG
  105.      DC.L    EndCode       ; APTR  RT_ENDSKIP
  106.      DC.B    RTF_AUTOINIT  ; UBYTE RT_FLAGS
  107.      DC.B    VERSION       ; UBYTE RT_VERSION
  108.      DC.B    NT_LIBRARY    ; UBYTE RT_TYPE
  109.      DC.B    MYPRI         ; BYTE  RT_PRI
  110.      DC.L    myName        ; APTR  RT_NAME
  111.      DC.L    idString      ; APTR  RT_IDSTRING
  112.      DC.L    Init          ; APTR  RT_INIT
  113.                ; LABEL RT_SIZE
  114.  
  115.  
  116.    ; this is the name that the library will have
  117. myName:      FSLIBNAME
  118.  
  119.    ; a major version number.
  120. VERSION:   EQU   1
  121.  
  122.    ; A particular revision.  This should uniquely identify the bits in the
  123.    ; library.  I use a script that advances the revision number each time
  124.    ; I recompile.  That way there is never a question of which library
  125.    ; that really is.
  126.  
  127. REVISION:   EQU   1
  128.  
  129.    ; this is an identifier tag to help in supporting the library
  130.    ; format is 'name version.revision (dd MON yyyy)',<cr>,<lf>,<null>
  131. idString:   dc.b   'future 1.0 (20 JUN 1986)',13,10,0
  132.  
  133. dosName:   DOSNAME
  134.  
  135.    ; force word allignment
  136.    ds.w   0
  137.  
  138.  
  139.    ; The romtag specified that we were "RTF_AUTOINIT".  This means
  140.    ; that the RT_INIT structure member points to one of these
  141.    ; tables below.  If the AUTOINIT bit was not set then RT_INIT
  142.    ; would point to a routine to run.
  143.  
  144. Init:
  145.    DC.L   MyLib_Sizeof   ; data space size
  146.    DC.L   funcTable      ; pointer to function initializers
  147.    DC.L   dataTable      ; pointer to data initializers
  148.    DC.L   initRoutine    ; routine to run
  149.  
  150.  
  151. funcTable:
  152.  
  153.    ;------ standard system routines
  154.    dc.l   Open
  155.    dc.l   Close
  156.    dc.l   Expunge
  157.    dc.l   Null
  158.  
  159.    ;------ my library function table
  160.    dc.l   FSGetSize
  161.    dc.l   FSLoadSound
  162.    dc.l   FSPlaySound
  163.    dc.l   FSStopSound
  164.  
  165.    ;------ function table end marker
  166.    dc.l   -1
  167.  
  168.  
  169.    ; The data table initializes static data structures.
  170.    ; The format is specified in exec/InitStruct routine's
  171.    ; manual pages.  The INITBYTE/INITWORD/INITLONG routines
  172.    ; are in the file "exec/initializers.i".  The first argument
  173.    ; is the offset from the library base for this byte/word/long.
  174.    ; The second argument is the value to put in that cell.
  175.    ; The table is null terminated
  176. dataTable:
  177.    INITBYTE   LH_TYPE,NT_LIBRARY
  178.    INITLONG   LN_NAME,myName
  179.    INITBYTE   LIB_FLAGS,LIBF_SUMUSED!LIBF_CHANGED
  180.    INITWORD   LIB_VERSION,VERSION
  181.    INITWORD   LIB_REVISION,REVISION
  182.    INITLONG   LIB_IDSTRING,idString
  183.    DC.L   0
  184.  
  185.  
  186.    ; This routine gets called after the library has been allocated.
  187.    ; The library pointer is in D0.  The segment list is in A0.
  188.    ; And A6 holds an exec pointer.
  189.    ; If it returns non-zero then the library will be linked into
  190.    ; the library list.
  191. initRoutine:
  192.  
  193.    ;------ get the library pointer into a convenient A register, A5
  194.    move.l   a5,-(sp)
  195.    move.l   d0,a5
  196.  
  197.    ;------ save a pointer to exec
  198.    move.l   a6,ml_SysLib(a5)
  199.  
  200. ; and save an exec pointer for Lattice, too.
  201.    move.l   a6,_SysBase
  202.  
  203.    ;------ save a pointer to our loaded code
  204.    move.l   a0,ml_SegList(a5)
  205.  
  206.    ;------ open the dos library
  207.    lea   dosName(pc),a1
  208.    CLEAR   d0
  209.    CALLSYS   OpenLibrary
  210.  
  211.    move.l   d0,ml_DosLib(a5)
  212.  
  213. ; and save a Dos pointer for Lattice, too.
  214.    move.l   d0,_DOSBase
  215.    bne.s   1$
  216.  
  217.    ;------ can't open the dos!  what gives
  218.    ALERT   AG_OpenLib!AO_DOSLib
  219.  
  220. 1$:
  221.  
  222. ; Build and initialize all application-specific data.
  223.  
  224. ; Aside from having the _SysBase and _DOSBase variables set, Lattice
  225. ; code compiled with the '-v' option on pass 2 doesn't need any other
  226. ; setup - if you don't use any special Lattice functions.
  227.  
  228. ; final library cleanup before exiting Init routine.
  229. ; restore A5 to be a pointer to our library, like what we got to start.
  230. ; Since this is non-zero, we will be added to the library list.
  231.    move.l   a5,d0
  232.    move.l   (sp)+,a5
  233.    rts
  234.  
  235.  
  236. ;----------------------------------------------------------------------
  237. ; Here begins the system interface commands.  When the user calls
  238. ; OpenLibrary/CloseLibrary/RemoveLibrary, this eventually gets translated
  239. ; into a call to the following routines (Open/Close/Expunge).  Exec
  240. ; has already put our library pointer in A6 for us.  Exec has turned
  241. ; off task switching while in these routines (via Forbid/Permit), so
  242. ; we should not take too long in them.
  243. ;----------------------------------------------------------------------
  244.  
  245.    ; Open returns the library pointer in d0 if the open
  246.    ; was successful.  If the open failed then null is returned.
  247.    ; It might fail if we allocated memory on each open, or
  248.    ; if only open application could have the library open
  249.    ; at a time...
  250.  
  251. Open:      ; ( libptr:a6, version:d0 )
  252.  
  253.    ;------ mark us as having another opener
  254.    addq.w   #1,LIB_OPENCNT(a6)
  255.  
  256.    ;------ prevent delayed expunges
  257.    bclr   #LIBB_DELEXP,ml_Flags(a6)
  258.  
  259.    move.l   a6,d0
  260.    rts
  261.  
  262.    ; There are two different things that might be returned from
  263.    ; the Close routine.  If the library is no longer open and
  264.    ; there is a delayed expunge then Close should return the
  265.    ; segment list (as given to Init).  Otherwise close should
  266.    ; return NULL.
  267.  
  268. Close:      ; ( libptr:a6 )
  269.     
  270.    ;------ set the return value
  271.    CLEAR   d0
  272.  
  273.    ;------ mark us as having one fewer openers
  274.    subq.w   #1,LIB_OPENCNT(a6)
  275.  
  276.    ;------ see if there is anyone left with us open
  277.    bne.s   1$
  278.  
  279.    ;------ see if we have a delayed expunge pending
  280.    btst   #LIBB_DELEXP,ml_Flags(a6)
  281.    beq.s   1$
  282.  
  283.    ;------ do the expunge
  284.    bsr   Expunge
  285. 1$:
  286.    rts
  287.  
  288.  
  289.    ; There are two different things that might be returned from
  290.    ; the Expunge routine.  If the library is no longer open
  291.    ; then Expunge should return the segment list (as given to
  292.    ; Init).  Otherwise Expunge should set the delayed expunge
  293.    ; flag and return NULL.
  294.    ;
  295.    ; One other important note: because Expunge is called from
  296.    ; the memory allocator, it may NEVER Wait() or otherwise
  297.    ; take long time to complete.
  298.  
  299. Expunge:   ; ( libptr: a6 )
  300.  
  301.    movem.l   d2/a5/a6,-(sp)
  302.    move.l   a6,a5
  303.    move.l   ml_SysLib(a5),a6
  304.    
  305.    ;------ see if anyone has us open
  306.    tst.w   LIB_OPENCNT(a5)
  307.    beq   1$
  308.  
  309.    ;------ it is still open.  set the delayed expunge flag
  310.    bset   #LIBB_DELEXP,ml_Flags(a5)
  311.    CLEAR   d0
  312.    bra.s   Expunge_End
  313.  
  314. 1$:
  315.    ;------ go ahead and get rid of us.  Store our seglist in d2
  316.    move.l   ml_SegList(a5),d2
  317.  
  318.    ;------ unlink from library list
  319.    move.l   a5,a1
  320.    CALLSYS   Remove
  321.    
  322. ; now perform application-specific cleanup
  323.  
  324. ; nothing to clean up from Lattice as specified above.
  325.  
  326. ; continue the library cleanup
  327.  
  328.    ;------ close the dos library
  329.    move.l   ml_DosLib(a5),a1
  330.    CALLSYS   CloseLibrary
  331.  
  332.    ;------ free our memory
  333.    CLEAR   d0
  334.    move.l   a5,a1
  335.    move.w   LIB_NEGSIZE(a5),d0
  336.  
  337.    sub.l   d0,a1
  338.    add.w   LIB_POSSIZE(a5),d0
  339.  
  340.    CALLSYS   FreeMem
  341.  
  342.    ;------ set up our return value
  343.    move.l   d2,d0
  344.  
  345. Expunge_End:
  346.    movem.l   (sp)+,d2/a5/a6
  347.    rts
  348.  
  349.  
  350. Null:
  351.    CLEAR   d0
  352.    rts
  353.  
  354. ;----------------------------------------------------------------------
  355. ; Here begins the library specific commands
  356. ;----------------------------------------------------------------------
  357.  
  358. ; Lattice places the function arguments on the stack in right-to-left
  359. ; declaration order, so the CALLED function takes them off in natural
  360. ; order.  So, here we take the register values as specified in
  361. ; 'future_lib.fd,' and put them on the stack for Lattice.
  362.  
  363. ; Lattice function return values are in D0 in these functions
  364.  
  365.  
  366. ; ULONG GetSize(filename)        (A0)
  367. ; char *filename;
  368. ;
  369. ; ULONG error code returned in D0.L
  370.  
  371. FSGetSize:
  372.    move.l   a0,-(a7)
  373.    jsr      _GetSize
  374.    add.w     #4,a7
  375.    rts
  376.  
  377. ; UWORD LoadSound(filename,buffer)  (D0,A0)
  378. ; char *filename;
  379. ; char *buffer;
  380. ;
  381. ; recording rate returned in D0
  382.  
  383. FSLoadSound:
  384.    move.l   a0,-(a7)
  385.    move.l   d0,-(a7)
  386.    jsr      _LoadSound
  387.    add.w    #8,a7
  388.    rts
  389.  
  390. ; struct IOAudio *PlaySound(buffer,buflen,repeat,period,volume) (A0,D0-D3)
  391. ; BYTE *buffer;
  392. ; ULONG buflen;
  393. ; long repeat,
  394. ;      period,
  395. ;      volume;
  396. ; 
  397. ; struct IOAudio pointer returned in D0.L
  398.  
  399. FSPlaySound:
  400.    movem.l  d0/d1/d2/d3,-(a7)    ; D3 is pushed first
  401.    move.l   a0,-(a7)
  402.    jsr      _PlaySound
  403.    add.w    #20,a7
  404.    rts
  405.  
  406.  
  407. ; StopSound(ioa)        (A0)
  408. ; struct IOAudio *ioa;
  409. ;
  410. ; no return value
  411.  
  412. FSStopSound:
  413.    move.l   a0,-(a7)
  414.    jsr      _StopSound
  415.    moveq    #0,d0
  416.    add.w    #4,a7
  417.    rts
  418.  
  419. ; Lattice data for these functions.
  420.  
  421.    XDEF   _DOSBase,_SysBase
  422.  
  423. _SysBase     DC.L 0
  424. _DOSBase     DC.L 0   
  425.  
  426.    ; EndCode is a marker that show the end of your code.
  427.    ; Make sure it does not span sections nor is before the
  428.    ; rom tag in memory!  It is ok to put it right after
  429.    ; the rom tag -- that way you are always safe.  I put
  430.    ; it here because it happens to be the "right" thing
  431.    ; to do, and I know that it is safe in this case.
  432. EndCode:
  433.  
  434.    END
  435.  
  436.